Group Company outstanding Parent Name not Fetched

Dear Experts
Any one give solution to get Parent Name in Group Company Outstanding Report



[collection:OSReport]
Type : Bills
; Child Of : $$GroupSundryDebtors
; Belongs TO : Yes
Fetch : *
Fetch : Company Name,LedgerName,BillDueDate,parent
Compute : Owner Company : $$LoopCollObj:$Name



[Collection: OsReportMultiComp]
Collection : OSReport : GrpCompanyColl1
; Compute : Owner Company : $Name
; Sort : Default : $Date, $LedgerName

[Collection: GrpCompanyColl1]

Type : Company
Fetch : *

 

use $Parent:Ledger:$LedgerName or $Parent:Ledger:$PartyLedgerName

 

Dear Mahbu,

Already Added the field, but it shows active company only, I want member company also

[Field: OSParent]
Use : NameField
Set As : $Parent:Ledger:$LedgerName

 

Dear Saro,
Try change collection GrpCompanyColl1
Type : Member List : Company
Child Of : ##SVCurrentCompany
Fetch : *

 

Dear Mahbu,
Thanks for your reply, still i'm not get the report, I shared full source for your reference,



[#Menu: Gateway of Tally]
Add : Item : Before@Locquit: BLANK
Add : Key Item : Before : @@Locquit :Group Os : O : Display : VchOSExp
Add : Item : After:SMS Sync: BLANK



[collection:OSReport]

Type : Bills
; Child Of : $$GroupSundryDebtors
; Child of : "Sundry Debtors"
; Belongs TO : Yes
Fetch : *
Fetch : Company Name,LedgerName,BillDueDate,parent
Compute : Owner Company : $$LoopCollObj:$Name
; Filter : SundryDebtors


[Collection: OsReportMultiComp]
Collection : OSReport : GrpCompanyColl1


[Collection: GrpCompanyColl1]

Type : Member List : Company
Child Of : ##SVCurrentCompany
Fetch : *


[Report:VchOSExp]
Form : VchOSExp


[Form: VchOSExp]
Part : OSLine


[Part: OSLine]
Line :OSLine,
Repeat : OSLine: OsReportMultiComp
Scroll: Vertical

[Line: OSLine]
Fields : OSCompname,OSBillNo,OSBilldate,OSCUSName,OSClsBal,OSBillDuedt,OSBILLOP,OSParent


[Field: OSCompname]
Use : NameField
Set As : $OwnerCompany

[Field: OSParent]
Use : NameField
Set As : $Parent:Ledger:$LedgerName

[Field: OSBillNo]
Use : NameField
Set As : $Name


[Field: OSBilldate]
Use : Uni Date Field
Set As : $Billdate


[Field: OSCUSName]
Use : NameField
Set As : $LedgerName


[Field: OSBILLOP]
Use : Amount Field
Set As : $OpeningBalance
Format : "DrCr"


[Field: OSClsBal]
Use : Amount Field
Set As : $ClosingBalance
Format : "DrCr"


[Field: OSBillDuedt]
Use : Uni Date Field
Set As : $BillDueDate

 

Dear Amit Sir,
Thanks for your support, I got the output, but if I filter the [collection:OSReport] I'm getting Current company result only sir


[collection:OSReport]

Type : Bills
Compute : Owner Company : $$LoopCollObj:$Name
Fetch : *
Fetch : Company Name,LedgerName,BillDueDate,
Compute : OwnerParent : $Parent:Ledger:$LedgerName
Filter : SundryDebtors

[System:Formulae]

SundryDebtors:$$IsLedOfGrp:$LedgerName:$$GroupSundryDebtors

 

Change formulae

SundryDebtors: ($ReserveName:Ledger:$LedgerName = $$GroupSundryDebtors)

 

Dear Mahbu,
getting current Company report only, its not shows for member company

 

Dear I checked me getting all company debtors bills

 

check this modified code

[#Menu: Gateway of Tally]
Add : Key Item : Before : @@Locquit :Group Os : O : Display : VchOSExp
[collection:OSReport]
Type : Bills
; Child Of : $$GroupSundryDebtors
; Child of : "Sundry Debtors"
; Belongs TO : Yes;
Fetch : *
Fetch : Company Name,LedgerName,BillDueDate,parent
Compute : Owner Company : $$LoopCollObj:$Name
Filter : SundryDebtors
Sort@dEFAULT:$BillDueDate
[System:Formulae]
SundryDebtors: ($ReserveName:Ledger:$LedgerName = $$GroupSundryDebtors);$$IsLedOfGrp:$OwnerLedger:$$GroupSundryDebtors
;SundryDebtors:$$IsLedOfGrp:$LedgerName:$$GroupSundryDebtors
[Collection: OsReportMultiComp]
Collection : OSReport : GrpCompanyColl1
[Collection: GrpCompanyColl1]
Type : Member List : Company
Child Of : ##SVCurrentCompany
;Belongs To:Yes
;Type:Company
Fetch : *
[Report:VchOSExp]
Form : VchOSExp
Variable:SvCurrentCompany
[Form: VchOSExp]
Part : OSLine
Height:100% Screen
Width : 100% screen
[Part: OSLine]
Line :OSLine,
Repeat : OSLine: OsReportMultiComp
Scroll: Vertical
[Line: OSLine]
Fields : OSCompname,OSBillNo,OSBilldate,OSCUSName,OSClsBal,OSBillDuedt,OSBILLOP,OSParent
[Field:Osreservname]
Use : NameField
Set As : $ReserveName:Ledger:$LedgerName
[Field: OSCompname]
Use : NameField
Set As : $OwnerCompany
Variable :SvCurrentCompany
Modifies:SvCurrentCompany
[Field: OSParent]
Use : NameField
Set As : $Parent:Ledger:$LedgerName
[Field: OSBillNo]
Use : NameField
Set As : $Name
[Field: OSBilldate]
Use : Uni Date Field
Set As : $Billdate
[Field: OSCUSName]
Use : NameField
Set As : $LedgerName
[Field: OSBILLOP]
Use : Amount Field
Set As : $OpeningBalance
Format : "DrCr"
[Field: OSClsBal]
Use : Amount Field
Set As : $ClosingBalance
Format : "DrCr"
[Field: OSBillDuedt]
Use : Uni Date Field
Set As : $BillDueDate

 

Dear Saro,
Above code working in group company
you have group company or multiple login company without group ?

 

please check this code it will work both Group & Single company

[#Menu: Gateway of Tally]
Add : Key Item : Before : @@Locquit :Group Os : O : Display : VchOSExp
[collection:OSReport]
Type : Bills
; Child Of : $$GroupSundryDebtors
; Child of : "Sundry Debtors"
; Belongs TO : Yes;
Fetch : *
Fetch : Company Name,LedgerName,BillDueDate,parent
Filter : SundryDebtors
Sort@dEFAULT:$BillDueDate
Option:OSReportGroupCmp:Not $$IsSimpleCompany:##SVCurrentCompany
[!Collection:OSReportGroupCmp]
Compute : Owner Company : $$LoopCollObj:$Name
[System:Formulae]
SundryDebtors: ($ReserveName:Ledger:$LedgerName = $$GroupSundryDebtors);$$IsLedOfGrp:$OwnerLedger:$$GroupSundryDebtors
;SundryDebtors:$$IsLedOfGrp:$LedgerName:$$GroupSundryDebtors
[Collection: OsReportMultiComp]
Collection : OSReport : GrpCompanyColl1
[Collection: GrpCompanyColl1]
Type : Member List : Company
Child Of : ##SVCurrentCompany
Belongs To:Yes
Fetch : *
[Report:VchOSExp]
Form : VchOSExp
Variable:SvCurrentCompany
[Form: VchOSExp]
Part : OSLine
Height:100% Screen
Width : 100% screen
[Part: OSLine]
Line :OSLine,
Repeat : OSLine: OsReportMultiComp
Scroll: Vertical
Option: OSLineGroupCmp:$$IsSimpleCompany:##SVCurrentCompany
[!Part: OSLineGroupCmp]
Repeat : OSLine: OSReport
[Line: OSLine]
Fields : OSCompname,OSBillNo,OSBilldate,OSCUSName,OSClsBal,OSBillDuedt,OSBILLOP,OSParent
[Field:Osreservname]
Use : NameField
Set As : $ReserveName:Ledger:$LedgerName
[Field: OSCompname]
Use : NameField
Set As : if Not $$IsSimpleCompany:##SvCurrentCompany then $OwnerCompany else ##SvCurrentCompany
Variable :SvCurrentCompany
Modifies:SvCurrentCompany
[Field: OSParent]
Use : NameField
Set As : $Parent:Ledger:$LedgerName
[Field: OSBillNo]
Use : NameField
Set As : $Name
[Field: OSBilldate]
Use : Uni Date Field
Set As : $Billdate
[Field: OSCUSName]
Use : NameField
Set As : $LedgerName
[Field: OSBILLOP]
Use : Amount Field
Set As : $OpeningBalance
Format : "DrCr"
[Field: OSClsBal]
Use : Amount Field
Set As : $ClosingBalance
Format : "DrCr"
[Field: OSBillDuedt]
Use : Uni Date Field
Set As : $BillDueDate

 

Dear Mahbu,
Thank for your support