Sales returns Report party and Rep wise

Dear Experts,
Please help me to get Sales Return,Party wise ,item Wise , rep wise report as like below mentioned sales Report

;===============================================================
;======================= F11 Feature ===========================
;===============================================================

[#Part: CMP TallyShopFeatures Left]
Add : Line : At End : CMP EnableRepLine

[Line:CMP EnableRepLine]
Space Bottom : 1.5 mms
Field : Long Prompt,CMP EnableRepLine
Local : Field : Long Prompt : Set as : "Enable Rep wise Report.?:"

[Field:CMP EnableRepLine]
Use : Logical Field
Storage : EnableRep
Set as : If $$IsEmpty:$$Value then "No" else $$Value
Sub Form: CMP RepNameReport: $$Value = "Yes"

[Report: CMP RepNameReport]
Form : CMP RepNameForm
Object : Company

[Form: CMP RepNameForm]
Part : CMPRepDetails
Background : White, Petal Pink

[Field:CMPName Field]
Use : Name Field
Skip : Yes
Align : Center
Border : Thin Bottom

[Part:CMPRepDetails]
Part : CMP RepNamePart,CMP TransportPart,CMP MnfPart
Vertical : No
Common Border : Yes

[Part: CMP RepNamePart]
Line : CMP RepNamePartTit,CMP RepName LineDetails
Repeat : CMP RepName LineDetails: RepNameList
BreakOn : $$IsEmpty:$RepNameList
Height : 10
Scroll : Vertical
CommonBorder: Yes
Space Left : 2 mms
Space Right : 2 mms
Border : Thin Right

[Line:CMP RepNamePartTit]
Field : CMPName Field
Local : Field : CMPName Field : Set as : "Rep Name"

[Line: CMP RepName LineDetails]
Field : CMP RepNameList;,CMP TransportList,CMP MnfList;,CMP Rep CommissionField

[Field: CMP RepNameList]
Use : Name Field
Storage : RepNameList
Style : Small Bold

[Part:CMP TransportPart]
Line : CMP TransportPartTit,CMP TransportPart
Repeat : CMP TransportPart: TransportList
BreakOn : $$IsEmpty:$TransportList
Height : 10
Scroll : Vertical
CommonBorder: Yes
Space Left : 2 mms
Space Right : 2 mms
Border : Thin Right

[Line:CMP TransportPartTit]
Field : CMPName Field
Local : Field : CMPName Field : Set as : "Transport Name"

[Line:CMP TransportPart]
Field : CMP TransportList

[Field: CMP TransportList]
Use : Name Field
Storage : TransportList
Style : Small Bold

[Part:CMP MnfPart]
Line : CMP MnfListTit,CMP MnfList
Repeat : CMP MnfList: MnfList
BreakOn : $$IsEmpty:$MnfList
Height : 15
Scroll : Vertical
CommonBorder: Yes
Space Left : 2 mms
Space Right : 2 mms

[Line:CMP MnfListTit]
Field : CMPName Field
Local : Field : CMPName Field : Set as : "Mnf Name"

[Line:CMP MnfList]
Field : CMP MnfList

[Field: CMP MnfList]
Use : Name Field
Storage : MnfList
Style : Small Bold

;===============================================================
;======================= Add Fields ===========================
;===============================================================

[#PartBLLINE Narration]
Add : Line : Before : VCH NarrPrompt : VCHRepLine

[Line:VCHRepLine]
Invisible : NOT $EnableRep:Company:##SVCurrentCompany OR NOT $$IsSales:##SVVoucherType
Field : VCHRepNameTit,VCHRepName,VCHTransportTit,VCHTransport,VCHMnfTit,VCHMnf

[Field:VCHRepNameTit]
Use : Meduim Prompt
Set as : "Rep Name :"
Skip : Yes

[Field:VCHTransportTit]
Use : VCHRepNameTit
Set as : "Transport Name :"

[Field:VCHMnfTit]
Use : VCHRepNameTit
Set as : "Mnf Name :"

[Field:VCHRepName]
Use : Name Field
Storage : RepName
Table : RepNameColl,EndofList
Show Table : Always
Key : CreateRep

[Field:VCHTransport]
Use : Name Field
Storage : TransportName
Table : TransportNameColl,EndofList
Show Table : Always
Key : CreateRep

[Field:VCHMnf]
Use : Name Field
Storage : MnfName
Table : MnfNameColl,EndofList
Show Table : Always
Key : CreateRep

[Key:CreateRep]
Key : Alt + C
Action : Alter : CMP RepNameReport

;;=========================================================
;;================= Rep wise Report ==================
;;=========================================================
[#Menu: Gateway of Tally]
Add : Key Item : After : @@locSalesRegister : "Rep Report" : R : Display : RepReport
;Control : RepReport : $EnableRep:Company:##SVCurrentCompany

[Report:RepReport]
Use : DSP Template
Title : "Rep Report"
Variable: SVFromDate, SVToDate
Repeat : Party Name
Form : RepReport
Set : SVFromDate : $$MonthStart:##SVCurrentDate
Set : SVToDate : $$MonthEnd:##SVCurrentDate
Set : FilterRep : ""
Set : FilterTransport : ""
Set : FilterMnf : ""

[Form:RepReport]
Button : PrintButton, ExportButton
Button : ExplodeFlag,ChangePeriod,BtnRep
Bottom Toolbar Buttons : EnterToEdit, BottomToolBarBtn8,BottomToolBarBtn9,BottomToolBarBtn10
Part : BWRTitle,BWRPeriod,BWRFilter,BWRDetails
Bottom Part :BWRTotals
Width : 75% Page
Space Left : 2 mms
Space Right : 2 mms

[Key: EnterToEdit]
Key : Enter
Title : $$LocaleString:"Explode"
Type : BottomToolBarBtn2
Action : Explode

[Part:BWRTitle]
Line : BWRTitle
Horizontal Align : Center

[Part:BWRPeriod]
Line : BWRPeriod

[Line:BWRTitle]
Field : Simple Field
Local : Field : Simple Field : Style : Large Bold
Local : Field : Simple Field : Info : "Sales Report"
Local : Field : Simple Field : Border: Thin Bottom
Local : Field : Simple Field : Align : Center

[Line:BWRPeriod]
Right Field : Name Field
Left Field : Short Prompt,RPTRepFilter
Local : Field : Name Field : Info : @@DSPDateStr
Local : Field : Name Field : Width : 50
Local : Field : Name Field : Align : Right
Local : Field : Short Prompt : Set as: "Rep:"
Local : Field : Short Prompt : Inactive: Not $EnableRep:Company:##SVCurrentCompany

[Part:BWRFilter]
Line : BWRTranFilter,BWRLMFilter
Invisible : Not $EnableRep:Company:##SVCurrentCompany

[Line:BWRTranFilter]
Field : Short Prompt,RPTTransportFilter
Space Top : 1 mms
Local : Field : Default : Use : Simple Field
Local : Field : Short Prompt : Set as : "Transport:"

[Line:BWRLMFilter]
Field : Short Prompt,RPTMnfFilter
Space Top : 1 mms
Local : Field : Default : Use : Simple Field
Local : Field : Short Prompt : Set as : "Mnf:"

[Field:RPTRepFilter]
Inactive : Not $EnableRep:Company:##SVCurrentCompany
Use : Simple Field
Style : Normal Bold
Set as : @VCHRepName
Set Always : Yes
VCHRepName : If $$IsEndOfList:##FilterRep or ##FilterRep="" Then "Show All" Else ##FilterRep

[Field:RPTTransportFilter]
Use : RPTRepFilter
Set as : @VCHTransport
VCHTransport : if ##FilterTransport="" or $$IsEndOfList:##FilterTransport Then "Show All" Else ##FilterTransport

[Field:RPTMnfFilter]
Use : RPTRepFilter
Set as : @VCHMnf
VCHMnf : if ##FilterMnf="" or $$IsEndOfList:##FilterMnf Then "Show All" Else ##FilterMnf


[Line:BWRHead]
Use : BWRDetails
Border : Column Titles
Local : Field : Default : Type : String
Local : Field : Default : Align : Center
Local : Field : Default : Border : Thin Left
Local : Field : Default : Style : Normal Bold
Local : Field : SWSno : Set as : "Sno"
Local : Field : SWSno : Border : Thin Left Right
Local : Field : BWRPartyName : Set as : "Party Name"
Local : Field : BWRPartyName : Align : Left
Local : Field : BWRActulQty : Set as : "Actual Qty"
Local : Field : BWRActulQty : Align : Left
Local : Field : BWRBilledQty : Set as : "Billed Qty"
Local : Field : BWRBilledQty : Align : Left
Local : Field : BWRAmount : Set as : "Amount"
Local : Field : BWRAmount : Border : Thin Left Right
Space Top : 1.5 mms
Space Bottom: 1.5 mms

[Part:BWRDetails]
Line : BWRHead,BWRDetails
Repeat : BWRDetails:BWRPartyWise
Scroll : Vertical
Total : BWRActulQty,BWRBilledQty,BWRAmount
Common Border : Yes

[Line:BWRDetails]
Field : SWSno,BWRPartyName
Right Field : BWRActulQty,BWRBilledQty,BWRAmount
Option : AlterOnEnter : $$IsVoucher
Space Bottom: 0.5 mms
Space Top : 0.5 mms
Border : Thin Top
Explode : BWRExplode : ($$KeyExplode OR ##ExplodeFlag)

[Field:BWRDefault]
Use : Name Field
Style : Normal Bold

[Field:SWSno]
Use : BWRDefault
Set as : $$Line
Width : 1.5 cm
Align : Center
Border : Thin Left Right

[Field:BWRPartyName]
Use : BWRDefault
Set as : $PartyName
Width : 60
Quick Search: Yes
Space Left : 2 mms

[Field:BWRActulQty]
Use : Qty Field
Type : Number
Set as : $TotActQty;VoucherTypeName
Width : 16
Space Left : 2 mms
Border : Thin Left Right

[Field:BWRBilledQty]
Use : BWRActulQty
Set as : $TotBillQty
Width : 16
Space Left : 2 mms
Border : Thin Right

[Field:BWRAmount]
Use : BWRDefault
Set as : $TotAmount
Type : Amount
Width : @@AmountWidth
Format : "No Zero, Symbol," + ##ShowForex
Align : Right
Key : Calculator
Max : @@MaxNumberWidth
Width : 16
Space Right : 2 mms
Border : Thin Right
Tooltip : "Amount Without TAX"

[Part:BWRTotals]
Line : BWRTotal

[Line:BWRTotal]
Border : Totals
Use : BWRDetails
Local : Field : Default : Type : String
Local : Field : Default : Align : Right
Local : Field : Default : Style : Large Bold
Local : Field : Default : Border : Thin Left
Local : Field : SWSno : Set as : ""
Local : Field : BWRPartyName : Set as : "Grand Total"
Local : Field : BWRActulQty : Set as : $$Total:BWRActulQty
Local : Field : BWRBilledQty : Set as : $$Total:BWRBilledQty
Local : Field : BWRAmount : Set as : $$Total:BWRAmount
Local : Field : BWRAmount : Border : Thin Left Right
Local : Field : BWRAmount : Align : Right

[Part:BWRExplode]
Line : BWRExplode
Repeat : BWRExplode:BWRPartyExplode
Border : Thin Bottom

[Line:BWRExplode]
Use : BWRDetails
Delete : Border
Local : Field : SWSno : Set as : ""
Local : Field : Default : Style : Normal Italic
Local : Field : BWRPartyName : Set as : $ItemName
Local : Field : BWRPartyName : Align : Right
Local : Field : BWRActulQty : Type : Quantity
Local : Field : BWRActulQty : Set as : $SubActQty
Local : Field : BWRBilledQty : Type : Quantity
Local : Field : BWRBilledQty : Set as : $SubBillQty
Local : Field : BWRAmount : Set as : $SubAmount

;===============================================================
;======================= Add Filters ===========================
;===============================================================

[Button:BtnRep]
Key : F5
Action : Execute : RepReportWise
Title : Rep Wise
Inactive: Not $EnableRep:Company:##SVCurrentCompany

[Report:RepReportWise]
Form : RepReportWise

[Form:RepReportWise]
Part : RepReportWise
Space Left : 2 mms
Space Right : 2 mms

[Part:RepReportWise]
Line : RepReportWise,FilterTransport,FilterMnf

[Line:RepReportWise]
Field : Medium Prompt,RepReportWise
Local : Field : Medium Prompt : Set as : "Select Rep Name:"
Space Bottom : 2 mms

[Field:RepReportWise]
Table : RepNameColl,EndOfList
ShowTable : Always
Use : Name Field
Width : 20
Border : Thin Box
Variable : FilterRep
Modifies : FilterRep

[Line:FilterTransport]
Field : Medium Prompt,FilterTransport
Local : Field : Medium Prompt : Set as : "Select Transport Name:"
Space Bottom : 2 mms

[Field:FilterTransport]
Table : TransportNameColl,EndOfList
ShowTable : Always
Use : Name Field
Width : 20
Border : Thin Box
Variable : FilterTransport
Modifies : FilterTransport

[Line:FilterMnf]
Field : Medium Prompt,FilterMnf
Local : Field : Medium Prompt : Set as : "Select Mnf Name:"
Space Bottom : 2 mms

[Field:FilterMnf]
Table : MnfNameColl,EndOfList
ShowTable : Always
Use : Name Field
Width : 20
Border : Thin Box
Variable : FilterMnf
Modifies : FilterMnf

;=============================================================
;================= System Functions =========================
;=============================================================

[System:UDF]
EnableRep : Logical : 4566
RepNameList : String : 4567
TransportList : String : 4568
MnfList : String : 4569
RepName : String : 4570
TransportName : String : 4571
MnfName : String : 4572

[System:Formula]
BWRFilter : $RepName=@@RepWise AND $TransportName=@@TransportWise AND $MnfName=@@MnfWise
RepWise : If $$IsEndOfList:##FilterRep or ##FilterRep="" Then $RepName Else ##FilterRep
TransportWise : If $$IsEndOfList:##FilterTransport or ##FilterTransport="" Then $TransportName Else ##FilterTransport
MnfWise : If $$IsEndOfList:##FilterMnf or ##FilterMnf="" Then $MnfName Else ##FilterMnf
BWRExplodeFilter: $PartyName=#BWRPartyName

[Collection: BWR Voucher]
Type : Vouchers : VoucherType
Child of : $$VchTypeSales
Belongs to : Yes
Fetch : Date,VoucherTypeName,PartyLedgerName,BasicPurchaseOrderNo,Amount,RepName,TransportName,MnfName
Filter : NOTIsOptionalVoucher,BWRFilter

[Collection:BWRPartyWise]
Source Collection : BWR Voucher
Walk : Inventory Entries
By : PartyName : $PartyLedgerName
Aggr Compute: TotActQty : Sum : $ActualQty
Aggr Compute: TotBillQty: Sum : $BilledQty
Aggr Compute: TotAmount : Sum : $Amount
Sort : Default : $PartyName

[Collection:BWRPartyExplode]
Source Collection : BWR Voucher
Walk : Inventory Entries
By : PartyName : $PartyLedgerName
By : ItemName : $StockItemName
Aggr Compute: SubActQty : Sum : $ActualQty
Aggr Compute: SubBillQty: Sum : $BilledQty
Aggr Compute: SubAmount : Sum : $Amount
Filter : BWRExplodeFilter

[Collection:RepNameColl]
Type : RepNameList: Company
Childof : ##SVCurrentCompany
Format : $RepNameList,25
Title : List of Reps

[Collection:TransportNameColl]
Type : TransportList: Company
Childof : ##SVCurrentCompany
Format : $TransportList,25
Title : List of Transports

[Collection:MnfNameColl]
Type : MnfList: Company
Childof : ##SVCurrentCompany
Format : $MnfList,25
Title : List of Mnfs

[Variable: PartyName2]
Type : String
Repeat : ##DSPRepeatCollection

[Variable:FilterRep]
Type : String

[Variable:FilterTransport]
Type : String

[Variable:FilterMnf]
Type : String

[System:Variables]
FilterRep : ""
FilterTransport : ""
FilterMnf : ""

 

someone share a tdl