How to Delete these lines

Discussion in 'Tally Developer' started by B4ALLB4U, Jul 29, 2019.

    
  1. B4ALLB4U

    B4ALLB4U New Member


    Dear Team

    I am from AndhraPradesh. I don't have much knowledge in Tally programming. I have added there lines after Company Address and the added showing in Invoice correctly. But unfortunately again these three lines are showing down from the Company address field.

    Pls advice me how to delete these unwanted lines ( which are marked orange color) from our code.

    Pls, find the below mentioned code.

    Code:
    [Part:GWLW Invoice Company Details]
    Left Part: GWLW Invoice Company Details Left
    Right Part: GWLW License Details
    Border: Thick Cover
    
    
    [Part:GWLW Invoice Company Details Left]
    Line: GWLW Company Name, GWLW Company Address
    Width:80% Page
    Space Left:1
    [Line: GWLW Company Name]
    Field: Name Field
    Local: Field: Name Field: Set as: @@CmpMailName
    Local: Field: Name Field: Style:GWLWT
    Local: Field: Name Field: Full Width: Yes
    
    [Line:GWLW Company Address]
    Field: Name Field
    Local: Field: Name Field: Set as: $$FullList:CompanyAddress:$Address
    Local: Field: Name Field: Full Width:Yes
    Local: Field: Name Field: Style:GWLW9bB
    Local: Field: Name Field: Line:4
    [Part:GWLW License Details]
    Line:GWLW PL No, GWLW FL No, GWLW SL No
    Border: Thick Left
    Common Border: yes
    Border:Thick Cover
    
    [Line:GWLW PL No]
    Field: Simple Prompt, Simple Field
    Local: Field: Simple Prompt: Set as: "Pesticide License No:"
    Local: Field: Simple Prompt: Width: 20
    Local: Field: Simple Field: Set as:2272
    Local: Field: Simple Field: Full Width:yes
    Local: Field: Simple Prompt: Style:GWLW9B
    Local: Field: Simple Field: Style:GWLW9B
    Space Top:0.25
    Space Bottom: 0.25
    Border: Thick Bottom
    [Line:GWLW FL No]
    
    Field: Simple Prompt, Simple Field
    Local: Field: Simple Prompt: Set as: "Fertiliser License No:"
    Local: Field: Simple Prompt: Width: 20
    Local: Field: Simple Field: Set as:KRI/17/ADDL.DA/FW/2017/24169
    Local: Field: Simple Field: Full Width:yes
    
    Local: Field: Simple Prompt: Style:GWLW9B
    Local: Field: Simple Field: Style:GWLW9B
    Space Top:0.25
    Space Bottom: 0.25
    Border: Thick Bottom
    [Line:GWLW SL No]
    
      Field: Simple Prompt, Simple Field
    Local: Field: Simple Prompt: Set as: "Seed License No:"
    Local: Field: Simple Prompt: Width: 20
    Local: Field: Simple Field: Set as: ""
    Local: Field: Simple Field: Full Width:yes
    Local: Field: Simple Prompt: Style:GWLW9B
    Local: Field: Simple Field: Style:GWLW9B
     
    Last edited: Jul 29, 2019


  2. Amit Kamdar

    Amit Kamdar Administrator Staff Member


    First as you mention...that "you have added"......means you know sufficient TDL knowledge to add fields, then it would be an easy to remove the unwanted.

    Second...this is code pirated by "Goodwill Learning World".... who are only best at pirating and copy/paste. However, compared to other LEECHERS, you must compliment them as they make the efforts to prefix or suffix their GWLW to all Reports/Forms/Parts/Line/Field as well as making their own Styles and formatting.

    Third, the code snippet you have appended about, there is nothing to be done in this part. You need to remove the LINES (as marked by you) from the appropriate PART.
     


  3. B4ALLB4U

    B4ALLB4U New Member


    Respected Sir

    Yes You are correct. I don't have much knowledge in TDL programming language. I am a PHP open source passionate. I am trying to learn tally tdl language.

    Yes Sir, I want to remove the LINES (as marked by me) from the appropriate PART.

    Regards

    B4ALLB4U
     


  4. Amit Kamdar

    Amit Kamdar Administrator Staff Member


    Am glad you are a learner and willing to learn hard..... but I have answered....please read the 3rd point in my earlier response. You have not appended the full code, so how can you be advised. So I have advised you to remove appropriate line from the appropriate part from your code.

    The code that you have shown here will remain as it is. No change.
     


  5. B4ALLB4U

    B4ALLB4U New Member


    Respected Sir

    As per your advice , I am here with forwarding my code ....

    Code:
    ;==================Goodwill Learning World=================;
    ;=============Customized Invoice print with Logo===========;
    ;=============Customized Invoice print with Logo===========;
    ;==================Goodwill Learning World=================;
    
    [Style:GWLW9]
    Font:Cambria
    Height:7
    [Style:B4ALLB4U]
    Font:Cambria
    Height:10
    
    [Style:GWLW9A]
    Font:Cambria
    Height:7.5
    [Style:GWLW9AB]
    Font:Cambria
    Height:9
    [Style:GWLW9ABb]
    Font:Cambria
    Height:9
    Bold:Yes
    
    [Style:GWLW9B]
    Font: Times New Roman
    Height:12
    Bold: Yes
    [Style:GWLWB]
    Font: Cambria
    Height:12
    Bold: Yes
    
    [Style: GWLW]
    Font: Times New Roman
    Height:13
    Bold: Yes
    
    
    [Style: GWLWT]
    Font: Engravers MT
    Height:15
    Bold: Yes
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;Invoice Customization Code Starts;;;;;;;;;;;;;;;;;;;;;;
    [#Part: VTYP BehaviourMain]
    Option  : GWLW Vch Type Confirmation: @@IsGWLWInv
    [!Part : GWLW Vch Type Confirmation]
      Add   : Line  : After : VTYP PrintSave :GWLW Confirm Vch Type
      
    [Line   : GWLW Confirm Vch Type]
    Field  : Long Prompt, Logical Field
    Local  : Field : Long Prompt  : Set as  : "Print Gst Format?"
    Local  : Field : Long Prompt  : Width  : @@LongWidth
    Local  : Field : Logical Field : Storage  : GWLWGWLWFormat
    
    [System : Formula]
    IsGWLWInv    : $$IsSales:$Parent
    IsGWLWCustomFormat  : $GWLWGWLWFormat:VoucherType:$VoucherTypeName
    [System : UDF]
      GWLWGWLWFormat : Logical  : 0001
    
    [#Form : Sales Color]
    Option: GWLW GWLW Invoice: @@IsGWLWCustomFormat
    [!Form:GWLW GWLW Invoice]
    Delete   : Print
    Add   : Print : GWLW Custom Invoice
    [Report :GWLW Custom Invoice]
    Use           : Printed Invoice
    Delete: Form        : Printed Invoice
    Form     : GWLW Custom Invoice
    [Form:GWLW Custom Invoice]
    Space Top   : 0.50 inch
        Space Right : 0.50 inch
        Space Left  : 0.50 inch
        Space Bottom: 0.50 inch
    
    Part: GWLW Opening Page Break, GWLW Invoice Body
    
    Bottom Part:GWLW GST analisys Bankdetails ledgerentries, GWLWInvoiceAmtwordandamount, GWLWSingnatureClosingBalanceTerms,GWLWJuri;;GWLW Invoice Total, GWLW Sing Off, GWLW Terms, GWLW Age, GWLW Jurisdiction
    
    
    [Part:GWLW Closing Page Break]
    Lines  :GWLW Closing Page Break Line
    
    [Line: GWLW Closing Page Break Line]
      Fields  : Simple Field
      Local  : Field: Simple Field : Set As : "Continued..."
      Local  : Field: Simple Field : FullWidth : Yes
      Local  : Field: Simple Field : Align  : Right
      Border  : Full Thin Top
    
    ;;;;;;;;;;;;;;;;;;;;;;;GWLW Opening Page Break;;;;;;;;;;;;;;;;;;;;;;;;;;;
    
    [Part:GWLW Opening Page Break]
    Part: GWLW Invoice Title, GWLW Invoice Company Details,GWLW License Details,GWLW Invoice Customer Details,GWLW Body Coloumns Title
    Vertical: yes
           
    [Part: GWLW Invoice Title]
    Line: GWLW Invoice Title
    Border: Thick Cover
                       
    [Line:GWLW Invoice Title]
    Field: Simple Field
    Right Field:Name Field
    Local: Field: Simple Field: Set as: "GST Tax Invoice"
    Local: Field: Simple Field: Style: Large BOLD
    Local: Field: Simple Field: Space Left: 40
    Local: Field: Simple Field: Full Width: No
    Local: Field: Name Field: Set as:If @@GetCopyNum = 1 Then "ORIGINAL FOR RECIPIENT" Else +
                If @@GetCopyNum = 2 Then $$LocaleString:"DUPLICATE FOR SUPPLIER" Else +
                 If @@GetCopyNum = 3 Then $$LocaleString:"TRIPLICATE FOR TRANSPOTER" Else +
                 If @@GetCopyNum = 4 Then $$LocaleString:"EXTRA COPY" Else $$LocaleString:"EXTRA COPY"
            
    Space Top: 0.25
    Space Bottom: 0.25
    [Part:GWLW Invoice Company Details]
    Left Part: GWLW Invoice Company Details Left
    Right Part: GWLW License Details
    Border: Thick Cover
    
       
    [Part:GWLW Invoice Company Details Left]
    Line: GWLW Company Name, GWLW Company Address
    Width:80% Page
    Space Left:1
    [Line: GWLW Company Name]
    Field: Name Field
    Local: Field: Name Field: Set as: @@CmpMailName
    Local: Field: Name Field: Style:GWLWT
    Local: Field: Name Field: Full Width: Yes
     
    [Line:GWLW Company Address]
    Field: Name Field
    Local: Field: Name Field: Set as: $$FullList:CompanyAddress:$Address
    Local: Field: Name Field: Full Width:Yes
    Local: Field: Name Field: Style:GWLW9bB
    Local: Field: Name Field: Line:4
    [Part:GWLW License Details]
    Line:GWLW PL No, GWLW FL No, GWLW SL No
    Border: Thick Left
    Common Border: yes
    Border:Thick Cover
    [Line:GWLW PL No]
    Field: Simple Prompt, Simple Field
    Local: Field: Simple Prompt: Set as: "Pesticide License No:"
    Local: Field: Simple Prompt: Width: 20
    Local: Field: Simple Field: Set as:2272
    Local: Field: Simple Field: Full Width:yes
    Local: Field: Simple Prompt: Style:GWLW9B
    Local: Field: Simple Field: Style:GWLW9B
    Space Top:0.25
    Space Bottom: 0.25
    Border: Thick Bottom
    [Line:GWLW FL No]
    
    Field: Simple Prompt, Simple Field
    Local: Field: Simple Prompt: Set as: "Fertiliser License No:"
    Local: Field: Simple Prompt: Width: 20
    Local: Field: Simple Field: Set as:KRI/17/ADDL.DA/FW/2017/24169
    Local: Field: Simple Field: Full Width:yes
    
    Local: Field: Simple Prompt: Style:GWLW9B
    Local: Field: Simple Field: Style:GWLW9B
    Space Top:0.25
    Space Bottom: 0.25
    Border: Thick Bottom
    [Line:GWLW SL No]
    
      Field: Simple Prompt, Simple Field
    Local: Field: Simple Prompt: Set as: "Seed License No:"
    Local: Field: Simple Prompt: Width: 20
    Local: Field: Simple Field: Set as: ""
    Local: Field: Simple Field: Full Width:yes
    Local: Field: Simple Prompt: Style:GWLW9B
    Local: Field: Simple Field: Style:GWLW9B
    
    
    
    
    
    
    
       
    
    [Part:GWLW Invoice Customer Details]
    Left Part: GWLW Customer Details Left
    Right Part: GWLW Invoice Details
    Border: Thick Cover
    [Part:GWLW Customer Details Left]
    Line: GWLW Customer Side Title,GWLW Customer Name, GWLW Customer Address,GWLW Customer State Name, GWLW Customer GST No
    Width:80% Page
    Space Left:1
    [Line:GWLW Customer Side Title]
    Field: Name Field
    Local: Field: Name Field: Set as: "Billed & Shipped To"
    Local: Field: Name Field: Full Width: Yes
    Local: Field: Name Field: Style:GWLW9bB
    Space Top: 0.20
    
    [Line:GWLW Customer Name]
    Field: Name Field
    Local: Field: Name Field: Set as: $PartyLedgerName
    Local: Field: Name Field: Full Width: Yes
    Local: Field: Name Field: Style:GWLWT
    Space Top:0.25
    
    
    [Line:GWLW Customer Address]
    Field: Name Field
    Local: Field: Name Field: Set as: $$FullList:BasicBuyerAddress:$BasicBuyerAddress
    Local: Field: Name Field: Full Width: Yes
    Local: Field: Name Field: Line: 0
    Local: Field: Name Field: Style:GWLW9bB
    
    [Line:GWLW Customer State Name]
    Field: Simple Field
    Local: Field: Simple Field: Set as: "State Name"+"  :  "+ $StateName +"  "+ "Code :"+"  "+ $$getgststatecode:@StateName
    Local: Field: Simple Field: Local Formula:StateName : If NOT ($$IsEmpty:$StateName OR $$IsSysName:NotApplicable:$StateName) Then $StateName Else $LedStateName:Ledger:@PartyName
    Local: Field: Simple Field: Full Width: Yes
    Local: Field: Simple Field: Style: GWLW9B
    [Line:GWLW Customer GST No]
    Fields  : Simple Prompt, Name Field
    Local   : Field : Simple Prompt: Set as  : "GSTNo.:"
    Local:Field:Simple Prompt:Width:15
    Local:Field: Simple Prompt: Style: GWLW9B
    Local : Field : Name Field : Set as : $PARTYGSTIN:Ledger:$LedgerName
    Local: Field: Name Field: Width:20
    Local: Field: Name Field: Style: GWLW9B
    
    
    
    [Part:GWLW Invoice Details]
    Line:GWLW Invoice Number Date, GWLW Delivery Challanno Date, GWLW eWayBillNo,GWLW Destination, GWLW Credit Days
    Border: Thick Left
    Common Border: No
    Border:Thick Cover
    Common Border:No
    [Line:GWLW Invoice Number Date]
    Field: Simple Prompt, Simple Field, Medium Prompt, Name Field
    Local: Field: Simple Prompt: Set as: "Invoice No:"
    Local: Field: Simple Prompt: Style: GWLW9B
    Local: Field: Simple Prompt: Width:20
    Local: Field: Simple Field: Set as: $VoucherNumber
    Local: Field: Simple Field: Style:GWLW9B
    Local: Field: Simple Field: Width:20
    Local: Field: Medium Prompt: Set as: "Date :"
    Local: Field: Medium Prompt: Width:10
    Local: Field: Medium Prompt: Style: GWLW9B
    Local: Field: Medium Prompt: Border: Thick Left
    Local: Field: Name Field: Set as: $Date
    Local: Field: Name Field: Style:GWLW9B
    Local: Field: Name Field: Width:12
    Space Top:0.25
    Space Bottom: 0.25
    Border: Thick Bottom
    [Line:GWLW Delivery Challanno Date]
    Use:GWLW Invoice Number Date
    Local: Field: Simple Prompt: Set as: "Challan No:"
    Local: Field: Simple Prompt: Style:GWLW9B
    Local: Field: Simple Field: Set as: $BasicShipDeliveryNote
      Local: Field: Simple Field: Width:20
    Local: Field: Simple Field: Style: GWLW9B
    Local: Field: Medium Prompt: Set as: "Date:"
    Local: Field: Medium Prompt: Style: GWLW9B
    Local: Field: Name Field: Set as: $BasicShippingDate
    [Line:GWLW eWayBillNo]
    Use:GWLW Invoice Number Date
    Local: Field: Simple Prompt: Set as: "e-Way Bill No:"
    
    Local: Field: Simple Field: Set as: If @@IsGSTewayApplicable Then @@GSTPrinteWayBillNumber Else +
           If $$IsEmpty:$VATTransBillNo Then $UDFVATWayBillNo Else $VATTransBillNo
    Local: Field: Simple Field: Width:20
    Local: Field: Medium Prompt: Set as: "Date:"
    
    Local: Field: Name Field: Set as: $Date
    
    [Line:GWLW Destination]
      Use:GWLW Invoice Number Date
    Local: Field: Simple Prompt: Set as: "Through.:"
    Local: Field: Simple Field: Set as: $BasicShippedBy
    Local: Field: Medium Prompt: Set as: "Vehical No.:"
    Local: Field: Name Field: Set as: $BasicShipVesselNo
    
    [Line:GWLW Credit Days]
      Field: Simple Prompt, Simple Field
    Local: Field: Simple Prompt: Set as: "Terms of Payment"
    Local: Field: Simple Prompt: Width: 15
    Local: Field: Simple Field: Set as:$BasicDueDateOfPymt
    Local: Field: Simple Field: Full Width:Yes
    Local: Field: Simple Prompt: Style:GWLW9B
    Local: Field: Simple Field: Style:GWLW9B
    
    ;;;;;;;;;;;;;;;;;;;;;;;INVOICE BODY STARTS;;;;;;;;;;;;;;;;;;;;;;;;;;
    [Part:GWLW Body Coloumns Title]
    Line: GWLW Coloumns Title1, GWLW Coloumns Title2
    Border: Thick Cover
    Common Border: Yes
    [Line: GWLW Coloumns Title1]
    Use: GWLW Invoice Body
    Local: Field: Default: Type: String
    Local: Field: Default: Style: GWLW9B
    Local: Field: Default: Align: Center
    Local: Field: GWLW SrNo: Set as: "Sr"
    Local: Field: GWLW Description:Set as:" Item "
    Local: Field: GWLW Batch No: Set as:"Batch"
    Local: Field: GWLW MFG Date: Set as:"MFG"
    Local: Field: GWLW EXP Date: Set as:"EXP"
    Local: Field: GWLW HSN Code: Set as:"HSN"
    Local: Field: GWLW Qty: Set as:"Qty in"
    Local: Field: GWLW Rate: Set as:"Rate"
    Local: Field:GWLW Discount: Set as: "Dis"
    Local: Field: GWLW GrossAmt: Set as:"Gross"
    [Line:GWLW Coloumns Title2]
    Use: GWLW Invoice Body
    Local: Field: Default: Type: String
    Local: Field: Default: Style: GWLW9B
    Local: Field: Default: Align: Center
    Local: Field: GWLW SrNo: Set as: "No"
    Local: Field: GWLW Description:Set as:"Description"
    Local: Field: GWLW Batch No: Set as:"No"
    Local: Field: GWLW MFG Date: Set as:"Date"
    Local: Field: GWLW EXP Date: Set as:"Date"
      Local: Field: GWLW HSN Code: Set as:"Code"
    Local: Field: GWLW Qty: Set as:"Units"
    Local: Field: GWLW Rate: Set as:""
    Local: Field:GWLW Discount: Set as: "%"
    Local: Field: GWLW GrossAmt: Set as:"Amount"
    Border: Thick Bottom
    
    [Part:GWLW Invoice Body]
    Line: GWLW Invoice Body
    Repeat:GWLW Invoice Body: Inventory Entries
    Bottom Line: GWLW Coloumn Total
    Border: Thick Cover
    Scroll: Vertical
    Float: no
    Common Border: Yes
    [Line: GWLW Invoice Body]
    Field: GWLW SrNo
    Right Field: GWLW Description, GWLW Batch No, GWLW MFG Date, GWLW EXP Date, GWLW HSN Code,GWLW Qty, +
        GWLW Rate, GWLW Discount,GWLW GrossAmt
    Space Top: 0.15
    Explode : EI DescExplosion : NOT $$IsEmpty:$StockItemName AND ##PRNWithItemDesc AND NOT $$IsEmpty:$BasicUserDescription   
    Local: Field: GWLW SrNo: Width:3
    Local: Field: GWLW Description: Width:6
    Local: Field: GWLW Batch No: Width:12
    Local: Field: GWLW MFG Date: Width:10
    Local: Field: GWLW EXP Date: Width:10
      Local: Field: GWLW HSN Code: Width:8
      Local: Field: GWLW Qty: Width:10
    Local: Field: GWLW Rate: Width: 10
    Local: Field:GWLW Discount: Width: 6
    Local: Field: GWLW GrossAmt: Width: 12
    Local: Field: GWLW SrNo: Border: Thick Right
    Local: Field: GWLW Batch No: Border: Thick Left
    Local: Field: GWLW MFG Date: Border: Thick Left
    Local: Field: GWLW EXP Date: Border: Thick Left
    Local: Field: GWLW HSN Code: Border: Thick Left
    Local: Field: GWLW Qty: Border: Thick Left
    Local: Field: GWLW Rate: Border: Thick Left
    Local: Field:GWLW Discount: Border: Thick Left
    Local: Field: GWLW GrossAmt: Border: Thick Left
    Space Top: 0.15
    [Field:GWLW SrNo]
    Use: Simple Field
    Set as: $$Line
    Style: B4ALLB4U
    Align: Center
    [Field:GWLW Description]
    Use: Simple Field
    Style: GWLW9B
    Set as: if NOT $$IsSysName:$StockItemName then @@InvItemName else ""
    Full Width: Yes
    Line: 0
    [Field:GWLW Batch No]
    Use:  Simple Field
    Set as:$BatchName
    Style: B4ALLB4U
    Align: Center
    [Field:GWLW MFG Date]
    Use:  Simple Field
    Set as:$MfdOn
    Style: B4ALLB4U
    Align : Center
    [Field:GWLW EXP Date]
    Use:  Simple Field
    Set as:$Expiryperiod
    Style: B4ALLB4U
    Align : Center
    [Field:GWLW HSN Code]
    Use:  Simple Field
    Set as:$GSTItemHSNCodeEx
    Style: B4ALLB4U
    Align: Center
    
    [Field:GWLW Qty]
    Use : Number Field ;; Qty Primary Field
    Format : "Primary"
    Set as: $BilledQty
    Style:GWLW9B
    Align: Center
    [Field:GWLW Rate]
    Use: Rate Price Field
    Set as: $Rate
    Style:GWLW9B
    Align: Center
    
    [Field:GWLW Discount]
    Use: Number Field
    Set as: ""
    Set as: $Discount
    Format      : "NoZero,Percentage"
    Style:GWLW9B
    
    [Field:GWLW Gross Amt]
    Use:Amount Forex Field
    Set as: $Amount
      Style: GWLW9
     
    
    
    Set Always: Yes
    Style:GWLW9B
    [Line:GWLW Coloumn Total]
    Use:GWLW Invoice Body
    Border: Thick Top Bottom
    
    Local: Field: GWLW SrNo: Set as: ""
    Local: Field: GWLW Description:Set as:"Total"
    Local: Field: GWLW Batch No: Set as:""
    Local: Field: GWLW MFG Date: Set as:""
    Local: Field: GWLW EXP Date: Set as:""
    Local: Field: GWLW HSN Code: Set as:""
    Local: Field: GWLW Qty: Set as:$$Total:Qty
    Local: Field: GWLW Rate: Set as:""
    Local: Field:GWLW Discount: Set as: ""
    Local: Field:GWLW Gross Amt: Set as: $$CollAmtTotal:InventoryEntries:$Amount
    [System: Formula]
    SGST        :$$FilterAmtTotal:LedgerEntries:SGST1:$Amount
    SGST1        :$Name:Ledger:$LedgerName Contains $$LocaleString:"SGST"
    CGST        :$$FilterAmtTotal:LedgerEntries:CGST1:$Amount
    CGST1        :$Name:Ledger:$LedgerName Contains $$LocaleString:"CGST"
    IGST        :$$FilterAmtTotal:LedgerEntries:IGST1:$Amount
    IGST1        :$Name:Ledger:$LedgerName Contains $$LocaleString:"IGST"
    Round        :$$FilterAmtTotal:LedgerEntries:Round1:$Amount
    Round1        :$Name:Ledger:$LedgerName Contains $$LocaleString:"Round"
    
    ;;;;;;;;;;;;;;;;GWLW Bottom Part;;;;;;;;;;;;;;;;;;;;;;;
    
    [Part:GWLW GST analisys Bankdetails ledgerentries]
    Left Part:VCH GST AnalysisDetails
    Right Part: GWLWBankDetails, GWLWLedgerEnteries
    Border: Thick Cover
    Common Border:Yes
    
    [#Part:VCH GST AnalysisDetails]
    Delete:Border   : Thin Box
    [#Part:VCH GST AnalysisDetails]
    Width:80% Page
    [Part:GWLWBankDetails]
    Use:EXPINV BankDetails
    Border: Thick Box
    [#Line: EXPINV BankTitle]
                 
                        Fields      : Simple Field
                        Local       : Field : Simple Field    : Set as    : $$LocaleString:"Bank A/c Details:"                           ;;; To Display Company's Bank Details
                        Local       : Field : Simple Field     : Full Width: Yes
                        Local        : Field : Simple Field     : Align : Center
         Local       : Field : Simple Field     : Style:GWLW9B
             Space Top:0.5
         Space Bottom:0.25
        
    [#Line: EXPINV BankName]
    
                        Fields      : Medium Prompt, EXPINV BankName
                        Local       : Field : Medium Prompt     : Set as  : $$LocaleString:"Bank Name :"                                      ;;; To Display Bank Name
                        Local       : Field : Medium Prompt     : Width     : 18% Page
         Local  : Field : Medium Prompt  : Style:GWLW9B
         Local  : Field:EXPINV BankName:Style:GWLW9B
    
                    [#Line: EXPINV BankAccNo]
    
                        Fields      : Medium Prompt, EXPINV BankAccountNo
                        Local       : Field : Medium Prompt    : Set as    : $$LocaleString:"A/c No. :"                                        ;;; To Display A/c No.
                        Local       : Field : Medium Prompt     : Width     : 18% Page
         Local  : Field : Medium Prompt  : Style:GWLW9B
         Local  : Field:EXPINV BankAccountNo:Style:GWLW9B
    
        [#Line: EXPINV BankBranchInfo]
    
                        Fields      : Medium Prompt, EXPINV BankBranchName
                        Local       : Field : Medium Prompt    : Set as    : $$LocaleString:"IFS Code :"                              ;;; To Display Branch & IFS Code
                        Local       : Field : Medium Prompt     : Width     : 20% Page
         Local  : Field : Medium Prompt  : Style:GWLW9B
         Local  : Field:EXPINV BankBranchName:Style:GWLW9B
    
    
    [Part:GWLWLedgerEnteries]
    Line:GWLWLedgerEnteries
    Repeat:GWLWLedgerEnteries:Ledger Entries
    Border: Thick Left
    Common Border: Yes
    ;Scroll: Vertical
    Float: No
    [Line:GWLWLedgerEnteries]
    Field: GWLWLedgerName,  GWLWLedgerAmount
    Remove if: $LedgerName = $PartyLedgerName
    [Field:GWLWLedgerName]
      Set as  : if ##SATCSDetails AND @@TaxLedgerHasTCS then $$LocaleString:"TCS : Income Tax" else +
             if NOT $$IsSysName:$LedgerName then $LedgerName else ""  ;;; used to print on invoice
       
            Style:GWLW9B
            Align       : Right
            FullWidth   : Yes
      AbatementVal: If $$Number:$STXAbatementRate = 0 Then $$String:"0" Else $$String:$STXAbatementRate
      LedNarr  : (@@IsSales AND ##SALedgerNarr) OR (@@IsPurchase AND ##PULedgerNarr) AND $$Filtercount:LedgerEntries:LedgerNarrFltr > 0
      Option  : LeftAlignField : @@AcctsInvoice
      Width:8.7
    
    
    
    [Field:GWLWLedgerAmount]
    Use         : Amount Forex Field 
    Set as      : $$SignedAmount:$Amount:@@VchOpposite
    Border: Thick box
    Align: Right
    Width: 15
    Style:GWLW9B
    [Part:GWLWInvoiceAmtwordandamount]
    Left Part: GWLWAmountinWord
    Right Part:GWLWInvoiceAmount
    Border: Thick Box
    Common Border: Yes
    [Part:GWLWAmountinWord]
    Line:GWLWAmountinWord
    [Line:GWLWAmountinWord]
    Field: Medium Prompt, Name Field
    Local: Field: Medium Prompt: Set as: "Amount In Words"
    Local: Field: Medium Prompt:Style:GWLW9B
    Local: Field: Name Field: Set as:$$InWords:$Amount +"  "+ "Only."
    Local: Field: Name Field: Full Width: Yes
    Local: Field: Name Field: Line:0
    Local: Field: Name Field:Style:GWLW9B
    Space Top:0.25
    Space Bottom:0.25
    
    [Part:GWLWInvoiceAmount]
    Line:GWLWInvoiceAmount
    [Line:GWLWInvoiceAmount]
    Field: Name Field, Amount Field
    Local: Field: Name Field: Set as: "Grand Total"
    Local: Field: Name Field: Border: Thick Left
    Local: Field: Name Field: Width:13
    Local: Field: Name Field: Align: Right
    Local: Field: Name Field: Style:GWLW9B
    Local: Field: Amount Field: Set as: $Amount
    Local: Field: Amount Field: Width:10
    Local: Field: Amount Field: Border: Thick Left
    Local: Field: Amount Field: Style:GWLW9B
    Space Top:0.25
    Space Bottom:0.25
    [Part:GWLWSingnatureClosingBalanceTerms]
    Left Part: GWLWTerms
    Right Part: GWLWCustomer Signature, GWLWSignature
    Border:Thick Box
    
    [Part:GWLWterms]
          Add            :Lines:Message0,Message1,Message2,Message3,Message4
          Border        :Left Totals
      [Line:Message0]
           Field        :title0
           [Field        :title0]
        Set as        :"Terms & Conditions:-"
        Style        :Normal Bold Italic
        FullWidth   :Yes
      [Line:Message1]
        Field        :title1
        [Field        :title1]
        Set as        :"1.Goods once sold cannot be taken back or exchanged."
        Style        :Normal
        FullWidth   :Yes
      [Line:Message2]
        Field        :title2
           [Field        :title2]
        Set as        :"2.Delayed/Default Payments if any will disqualify for all the discounts."
        Style        :Normal
        FullWidth   :Yes
      [Line:Message3]
        Field        :title3
           [Field        :title3]
        Set as        :"3.Interest @ 18% P.A.will be charged after due date."
        Style        :Normal
        FullWidth   :Yes
      [Line:Message4]
        Field        :title4
           [Field        :title4]
        Set as        :"4.We accept no responsibility after the goods are handover to transporter."
        Style        :Normal
        FullWidth   :Yes
    
    
    
    [Part:GWLWCustomer Signature]
    Line: For GWLWCustomer Signature, GWLWAcceptance
    Border:Thick Box
    
    [Line:For GWLWCustomer Signature]
    Field: Name Field
    Local: Field: Name Field: Set as: "For" +" "+ @@SimpleOtherPartyName
    Local: Field: Name Field: Full Width: Yes
    Local: Field: Name Field: Style: GWWB
    Local: Field: Name Field: Align: Center
    Space Top:0.5
    
    [Line:GWLWAcceptance]
    Field: Name Field
    Local: Field: Name Field: Set as: "Material Received in Good Condition."
    Local: Field: Name Field: Full Width: Yes
    Local: Field: Name Field: Style: GWW09
    Local: Field: Name Field: Line:0
    Local: Field: Name Field: Align: Center
    Space Top:3
    
    
    [Part:GWLWSignature]   
    Line: ForGWLWSignature, GWLWAuthorised
    Border:Thick Box
    Width:36.5
    
    [Line:ForGWLWSignature]
    Field: Name Field
    Local: Field: Name Field: Set as: "For" +" "+ @@CmpMailName
    Local: Field: Name Field: Full Width: Yes
    Local: Field: Name Field: Style: GWWB
    Local: Field: Name Field: Align: Center
    Space Top:0.5
    
    [Line:GWLWAuthorised]
    Field: Name Field
    Local: Field: Name Field: Set as: "Authorized Signatory"
    Local: Field: Name Field: Full Width: Yes
    Local: Field: Name Field: Style: GWWB
    Local: Field: Name Field: Align: Center
    Space Top:3
    
    [Part:GWLWJuri]
    Line:GWLW Juridiction
    
    [Line:GWLW Juridiction]
    Field: Name Field
    Local: Field: Name Field: Full Width: Yes
    Local: Field: Name Field: Set as: "Subject To VIJAYAWADA Jurisdiction Only."
    Local: Field: Name Field: Align: Center
    
    
    ;==================Goodwill Learning World=================;
    ;=============Customized Invoice print with Logo===========;
    ;=============Customized Invoice print with Logo===========;
    ;==================Goodwill Learning World=================;
    Pls guide me sir
     


  6. Ria

    Ria Member


    From [Part:GWLW Opening Page Break],
    remove part GWLW License Details
     
    Amit Kamdar likes this.


  7. Amit Kamdar

    Amit Kamdar Administrator Staff Member


    Follow above advice...............
     
    B4ALLB4U likes this.


  8. B4ALLB4U

    B4ALLB4U New Member


    Respected Sir

    Excellent support.thanks a lot for both people, who guided me a lot. @Ria @Amit Kamdar Sir ................................
     


  9. B4ALLB4U

    B4ALLB4U New Member


    Dear Masters!

    Greetings of the Day!

    PLs, help me on how to add the Tally e-Invoice details i.e IRN No, Ack No, Date, and QR code to the above tally single page invoice code.
     


Share This Page