Period Range not showing = Please help ????

Hello Sir
can anyone please help in period showing

code also attached ....

see attached pic ..

 

Try This

Code:

;---------------------------------------------------------------average_rate



[#Menu : Gateway of Tally]
Item : Item Sales Average_RATE : Display :LearnwellItemSumm42
[Report :LearnwellItemSumm42]
Form :LearnwellItemSumm
Variable : SVFromDate,SVToDate
Set : SVFromDate : SVfromDate:$$FinYearBeg:##StartDate:$StartingFrom:Company:##SVCurrentCompany
Set : SVToDate : $$MonthEnd:##SVFromdate ;;$$Machinedate  ;;
[Form :LearnwellItemSumm]
Part : LXTitle,LWSummItemTitle,LWSummItemDetail
Button : Change Period,Print Button,Export Button
Bottom Part : LWSummItemDetailBTM
Background :Light Lily Yellow ;White


[Part : LXTitle]
Line :partyaddL59

[Line:partyaddL59]
Field:partyaddL43

[Field:partyaddL43]
Fields:Simple Prompt, Name Field
Local:Field:simple prompt : info :$$localestring:"Period.:"
Local : Field : simple prompt : color : WHITE
Local : Field : simple prompt :Background:leaf green
Local : Field :simple prompt : style : SMALL bold
Local : Field : simple prompt : width : 14
Local : Field : name Field :Set as : @@DSPDateStr     ;$$String:##SVFromDate + " to " + $$String:##SVToDate
Local : Field : name Field :Set Always:Yes
Local : Field : name Field :Skip:Yes
Local : Field :name Field : width : 30
Local : Field :name Field : space left : 4
Local : Field :name Field : style : SMALL bold


[Part : LWSummItemTitle]
Use : LWSummItemDetail
Delete : Repeat
Delete : Scroll
Border : ColumnTitles
Local : Field : Default : Type : string
Local : Field : LWSummItemDetailItem : Set As : "Particulars"
Local : Field : LWHsn : Set As : "HSN Code"
Local : Field : LWGstperc : Set As : "GST Rate"
Local : Field : LWQtyTTl: Set As : "Sales Qty"
Local : Field : LWItmRate : Set As : "Avg. Rate"
Local : Field : LWAmtTTl : Set As : "Sales Value"
Local :Field : Default : Style : Small Bold
[Part :LWSummItemDetail]
Line : LWSummItemDetail
Repeat : LWSummItemDetail :LWCollSalesItems
Scroll : Vertical
Total : LWQtyTTl,LWAmtTTl
[Line :LWSummItemDetail]
Field : LWSummItemDetailItem,LWHsn,LWGstperc
Right Field : LWQtyTTl,LWItmRate,LWAmtTTl
Border : Thin bottom


[Field : LWSummItemDetailItem]
Set As : $Stockitem
Style : Small
Display : Item Monthly Summary
Variable : StockitemName
Width:33


[Field : LWHsn]
Use: Name Field
Set as:$(Stockitem,$stockitem).GstDetails[Last].hsncode
Style : Small
Width:10
color: leaf green
Align: left
Set Always: Yes
Skip: Yes

[Field : LWGstperc]
Use: Number Field
Set as:$(Stockitem,$stockitem).GSTDetails[First].StatewiseDetails[1, @@IsAnyState].RateDetails[1, @@IsIGST].GSTRate
Format: Percentage
Style : Small
Width:10
Align: left
color: blue
Set Always: Yes
Skip: Yes

[Field : LWQtyTTl]
Use : Qty Primary Field
Style : Small
Set As : $BilledQtyToT

[Field : LWItmRate]
Use : Rate Price Field
Set as : $AmountToT / $BilledQtyToT
Style : Small
color: geranium
Width:15

[Field : LWAmtTTl]
Use : Amount Field
Set As : $AmountToT
Style : Small
Width:18

[Part : LWSummItemDetailBTM]
Use : LWSummItemDetail
Delete : Repeat
Delete : Scroll
Delete : Total
Border : Totals
Local : Field : LWSummItemDetailItem : Set As : "Total"
Local : Field : LWQtyTTl: Set As : $$Total:LWQtyTTl
Local : Field : LWAmtTTl : Set As : $$Total:LWAmtTTl
Local :Field : Default : Style : Small Bold
[Collection : LearnwellItemSummcoll]
Type : Vouchers : VoucherType
Child of : $$VchTypeSales
Belongs to : yes
Fetch : Date,Inventory Entries
Compute : FromDate  :$$Date:$$String:$MonthStart
Compute : EndDate    :$$Date:$$String:$MonthEnd
[Collection : LWCollSalesItems]
Source Collection : LearnwellItemSummcoll
Walk : Inventory Entries
By : Stockitem : $StockitemName
Aggr Compute : BilledQtyToT : Sum : $BilledQty
Aggr Compute : AmountToT : Sum : $Amount

 

thanks

can stock name be sort by name ascending ... by stock name
as default in tally as shown in pic