TDL Suggestion

Discussion in 'Tally Developer' started by PRAPTI, Jul 4, 2019.

    
Tags:
?

The TDL

Poll closed Jul 11, 2019.
  1. Is absolutely correct.

    0 vote(s)
    0.0%
  2. Need some improvements..I am commenting here.

    0 vote(s)
    0.0%
  1. PRAPTI

    PRAPTI Member


    Hey! Does the given TDL need something which has not been provided??
    Code:
    [#Part: VTYP BehaviourMain]
    Option  : VTYP BehaveMain OTS VchTypeConfirm : @@IsOTSVchType
    [!Part : VTYP BehaveMain OTSVchTypeConfirm]
      Add   : Line  : After : VTYP PrintSave :VTYP OTS VchTypeConfirm
      
    [Line   : VTYP OTS VchTypeConfirm]
    Field  : Long Prompt, Logical Field
    Local  : Field : Long Prompt  : Set as  : "Print GST Format ?"
    Local  : Field : Long Prompt  : Width  : @@LongWidth
    Local  : Field : Logical Field : Storage  : OTSVchTypeConfirm1
    
    [System : Formula]
    IsOTSVchType   : $$IsSales:$Parent
    IsOTSNewAllow   : $OTSVchTypeConfirm1:VoucherType:$VoucherTypeName
    [System : UDF]
    OTSVchTypeConfirm1 : Logical  : 1781
    [#Form : Sales Color]
    Option: OTSSalesOTS Color: @@IsOTSNewAllow
    [!Form:OTSSalesOTS Color]
    Delete   : Print
    Add   : Print : STC GST INVOICE OTS
    [Report :STC GST INVOICE OTS]
    Use           : Printed Invoice
    Delete: Form        : Printed Invoice
    Form     : STC GST INVOICE OTS
    [Form:STC GST INVOICE OTS]
    Space Left: 0.50 Inch
    Space Bottom: 0.50 Inch
    Space Right: 0.50 Inch
    Space Top:0.50 Inch
    Part: OTS Opening Page Break, OTS Invoice Body
    Bottom Part:OTS GST analisys Bankdetails ledgerentries, OTSInvoiceAmtwordandamount, OTSSingnatureClosingBalanceTerms,OTSJuri;;OTS Invoice Total, OTS Sing Off, OTS Terms, OTS Age, OTS Juridiction
    Page Break : ClOTS Page Break, OTS Opening Page Break
    [Part:ClOTS Page Break]
    Lines  : GIOTS ClPgBrk
    
    [Line: GIOTS ClPgBrk]
      Fields  : Simple Field
      Local: Field: Simple Field : Set As : "Continued..."
      Local: Field: Simple Field : FullWidth : Yes
      Local: Field: Simple Field : Align  : Right
      Border  : Full Thin Top
    
    
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    
    [Style: P9]
    Font: Calibri (Body)
    Height: 9
    [Style:P10]
    Font:Calibri (Body)
    Height:10
    
    [Style:P9B]
    Use:P9
    Bold : Yes
    [Style:P9Bold]
    Use: P9
    Bold: Yes
    [Style: Parth CMP Name]
    Font: Vivaldi
    Height:20
    Bold : Yes
    Italic:Yes
    
    [Style: P8]
    Height: 5
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    [Part: OTS Opening Page Break]
    Part: OTS Invoice Title, OTS CMP Details, OTS Leading Details, OTS Coloumn Titles
    Vertical: Yes
    [Part:OTS Invoice Title]
    Line:OTS Invoice Title
    [Line:OTS Invoice Title]
    Field: Simple Field,Simple Prompt
    Right Field:Name Field
    Local: Field: Simple Field: Set as: "TAX INVOICE"
    Local: Field: Simple Field: Style: Large Bold Italic
    Local: Field: Simple Field: Space Left: 38
    Local: Field: Simple Field: Full Width: Yes
    Local: Field: Name Field: Set as:If @@GetCopyNum = 1 Then "ORIGINAL FOR RECIPIENT" Else +
                If @@GetCopyNum = 2 Then $$LocaleString:"DUPLICATE FOR TRANSPOTER" Else +
                 If @@GetCopyNum = 3 Then $$LocaleString:"TRIPLICATE FOR SUPPLIER " Else +
                 If @@GetCopyNum = 4 Then $$LocaleString:"EXTRA COPY" Else $$LocaleString:"EXTRA COPY"
    
              ;;
    [Part:OTS CMP Details]
      Part: OTS CMP Name Details
    [Part: OTS CMP Name Details]
    Line: OTS CMP Name, OTS CMP Address, OTS CMP Contact Details
    [Line: OTS CMP Name]
    Field: Name Field
    Local: Field: Name Field: Set as: @@CmpMailName
    Local: Field: Name Field: Style:Parth CMP Name
    Local: Field: Name Field: Full Width: Yes
    [Line:OTS CMP Address]
    Field: Name Field
    Local: Field: Name Field: Set as: $$FullList:CompanyAddress:$Address
    Local: Field: Name Field: Full Width: Yes
    Local: Field: Name Field: Style:P9
    Local: Field: Name Field: Line:0
    [Line:OTS CMP Contact Details]
    Field: Medium Prompt, Simple Field, Simple Prompt, Name Field
    Local: Field: Medium Prompt: Set as: "Contact No"
    Local: Field: Medium Prompt: Style: P9B
    Local: Field: Simple Field: Style: P9
    Local: Field: Simple Field: Set as: $PhoneNumber:Company:##SVCurrentCompany +"  "+ $MobileNumbers:Company:##SVCurrentCompany
    [Part:OTS Leading Details]
    Left Part: OTS Customer Details
    Right Part: OTS Invoice Details
    Border: Thick Cover
    [Part:OTS Customer Details]
    Line:OTS Customer Details Title, OTS Customer Name, OTS Customer Address, OTS Customer State Name, OTS Customer GST No
    Width: 70% Page
     
    [Line:OTS Customer Details Title]
    Field: Simple Field
    Local: Field: Simple Field : Set as: "Details for Buyer (Billed & Shipped To )"
    Local: Field: Simple Field: Style:P9B
    Local: Field: Simple Field: Full Width: Yes
    [Line:OTS Customer Name]
    Field: Simple Field
    Local: Field: Simple Field: Set as: @@SimpleOtherPartyName
    Local: Field: Simple Field: Style: P9B
    Local: Field: Simple Field: Full Width: Yes
    Space Top:1
    [Line:OTS Customer Address]
    Field: Simple Field
    Local: Field: Simple Field: Set as: $$FullList:BasicBuyerAddress:$BasicBuyerAddress
    Local: Field: Simple Field: Style: P9
    Local: Field: Simple Field: Full Width: Yes
    Local: Field: Simple Field: Line:0
    [Line:OTS Customer State Name]
    Field: Simple Field
    Local: Field: Simple Field: Set as: "State Name"+"  :  "+ $StateName +"  "+ "Code :"+"  "+ $$getgststatecode:@StateName
    Local: Field: Simple Field: Local Formula:StateName : If NOT ($$IsEmpty:$StateName OR $$IsSysName:NotApplicable:$StateName) Then $StateName Else $LedStateName:Ledger:@PartyName
    Local: Field: Simple Field: Full Width: Yes
    Local: Field: Simple Field: Style: P9
    [Line:OTS Customer GST No]
    Field: Simple Field
    Local: Field: Simple Field: Set as: "GSTIN No : " +" "+ $PartyGSTIN
    Local: Field: Simple Field: Full Width: Yes
    Local: Field: Simple Field: Style: P9
    [Part:OTS Invoice Details]
    Line: OTS Invoice No, OTS Invoice Date, OTS Vechile No , EBY eWayBillNo
    Width: 61% Page
    Border: Thin Left
    [Line:OTS Invoice No]
    Field: Medium Prompt,Simple Field
    Local: Field: Medium Prompt: Set as: "Invoice No"
    Local: Field: Medium Prompt: Style: P9B
    Local: Field: Medium Prompt: Width: 15
    Local: Field: Simple Field: Set as: $VoucherNumber
    Local: Field: Simple Field: Style: P9
    Local: Field: Simple Field: Full Width: Yes
    Space Top:1
    [Line:OTS Invoice Date]
    Field: Medium Prompt, Simple Field
    Local: Field: Medium Prompt: Set as: "Dated"
    Local: Field: Medium Prompt: Style: P9B
    Local: Field: Medium Prompt: Width: 15
    Local: Field: Simple Field: Set as: $Date
    Local: Field: Simple Field: Style: P9
    Local: Field: Simple Field: Full Width: Yes
     
    [Line:OTS Vechile No]
    Field: Medium Prompt, Simple Field, Simple Prompt
    Local: Field: Medium Prompt: Set as: "Vechile No. : "
    Local: Field: Medium Prompt: Style: P9B
    Local: Field: Simple Field: Set as:@@EIBasicShippedBy
    Local: Field: Medium Prompt: Width: 15
    Local: Field: Simple Field: Style: P9
    Local: Field: Simple Field: Full Width: Yes
     
    [Line:EBY eWayBillNo]
    Field: Medium Prompt, Simple Field, Simple Prompt
    Local: Field: Medium Prompt: Set as: "E-Way Bill No. :  "
    Local: Field: Simple Field: Set as:@@GSTPrinteWayBillNumber
    Local: Field: Medium Prompt: Style: P9B
    Local: Field: Medium Prompt: Width: 15
    Local: Field: Simple Field: Style: P9
    Local: Field: Simple Field: Full Width: Yes
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    [Part:OTS Coloumn Titles]
    Line:OTS Invoice Body Title,OTS Invoice Body Title1
    Border: Thick Cover
    Common Border: Yes
    
    [Part: OTS Invoice Body]
    Part:OTS Invoice Body Coloumns
    Vertical: Yes
    Border: Thin Cover
    [Part:OTS Invoice Body Title]
    Line:OTS Invoice Body Title,OTS Invoice Body Title1
    Common Border: Yes
    [Line:OTS Invoice Body Title]
    Use: OTS Invoice Body Coloumns
    Local: Field: Default: Type: String
    Local: Field: Default: Style: P9B
    Local: Field: Default: Align: Center
    Local: Field:OTS SrNo: Set as: "Sr "
    Local: Field:OTS Item Description: Set as: "Item"
    
    Local: Field:OTS HSN Code: Set as: "HSN "
    
    Local: Field:OTS Billed Qty: Set as: "Billed"
    Local: Field: OTS Rate: Set as: "Rate"
    Local: Field:OTS Discount: Set as: "Dis"
    Local: Field:OTS Gross Amt: Set as: "Gross"
    Local: Field:OTS GST Per: Set as: "GST"
    Local: Field:OTS CGST Rate: Set as: "CGST"
    Local: Field: OTS CGST Amt: Set as: "CGST"
    Local: Field:OTS SGST Rate: Set as: "SGST"
    Local: Field:OTS SGST Amt: Set as: "SGST "
    Local: Field:OTS IGST Rate: Set as: "IGST"
    Local: Field:OTS IGST Amount: Set as: "IGST"
    Local: Field:OTS Item Total: Set as: "Total"
    Border: Thin Top
    Space Top: 0.25
    [Line:OTS Invoice Body Title1]
    Use: OTS Invoice Body Coloumns
    Local: Field: Default: Type: String
    Local: Field: Default: Style: P9B
    Local: Field: Default: Align: Center
    Local: Field:OTS SrNo: Set as: "No"
    Local: Field:OTS Item Description: Set as: "Description"
    Local: Field:OTS HSN Code: Set as: "Code"
    Local: Field:OTS Billed Qty: Set as: "Qty"
    Local: Field: OTS Rate: Set as: ""
    Local: Field:OTS Discount: Set as: "%"
    Local: Field:OTS Gross Amt: Set as: "Amount"
    Local: Field:OTS GST Per: Set as: "%"
    Local: Field:OTS CGST Rate: Set as: "%"
    Local: Field: OTS CGST Amt: Set as: "Amt"
    Local: Field:OTS SGST Rate: Set as: "%"
    Local: Field:OTS SGST Amt: Set as: "Amt"
    Local: Field:OTS IGST Rate: Set as: "%"
    Local: Field:OTS IGST Amount: Set as: "Amt"
    Local: Field:OTS Item Total: Set as: ""
    Border: Thin Bottom
    Space Bottom: 0.25
    [Part:OTS Invoice Body Coloumns]
    Line:OTS Invoice Body Coloumns
    Repeat:OTS Invoice Body Coloumns:Inventory Entries
    Scroll: Vertical
    Float: No
    Common Border: Yes
    [Line:OTS Invoice Body Coloumns]
    Left Field: OTS SrNo, OTS Item Description, OTS Item Description1
    Right Field: OTS HSN Code,OTS Billed Qty, OTS Rate, OTS Discount, OTS Gross Amt, OTS GST Per,OTS CGST Rate, OTS CGST Amt, OTS SGST Rate, OTS SGST Amt,OTS IGST Rate, OTS IGST Amount, OTS Item Total
    Space Top: 0.15
    Explode     : EI DescExplosion       : NOT $$IsEmpty:$StockItemName AND ##PRNWithItemDesc AND NOT $$IsEmpty:$BasicUserDescription
    Local: Field:OTS SrNo: Width: 3
    Local: Field:OTS HSN Code: Width: 7
    
    Local: Field:OTS Billed Qty: Width: 7
    Local: Field: OTS Rate: Width: 7
    Local: Field:OTS Discount: Width: 3
    Local: Field:OTS Gross Amt: Width: 7
    Local: Field:OTS GST Per: Width: 3
    Local: Field:OTS CGST Rate: Width: 3
    Local: Field: OTS CGST Amt: Width: 7
    Local: Field:OTS SGST Rate: Width: 3
    Local: Field:OTS SGST Amt: Width: 7
    Local: Field:OTS IGST Rate: Width:3
    Local: Field:OTS IGST Amount: Width:7
    Local: Field:OTS Item Total: Width: 8
    Local: Field:OTS SrNo: Border: Thin Right
    Local: Field:OTS Part No: Border: Thin Left
    Local: Field:OTS HSN Code: Border: Thin Left
    Local: Field:OTS MRP Qty: Border: Thin Left
    Local: Field:OTS Shipped:Border: Thin Left
    Local: Field:OTS Billed Qty: Border: Thin Left
    Local: Field: OTS Rate: Border: Thin Left
    Local: Field:OTS Discount: Border: Thin Left
    Local: Field:OTS Gross Amt: Border: Thin Left
    Local: Field:OTS GST Per: Border: Thin Left
    Local: Field:OTS CGST Rate: Border: Thin Left
    Local: Field: OTS CGST Amt: Border: Thin Left
    Local: Field:OTS SGST Rate: Border: Thin Left
    Local: Field:OTS SGST Amt: Border: Thin Left
    Local: Field:OTS IGST Rate: Border: Thin Left
    Local: Field:OTS IGST Amount: Border: Thin Left
    Local: Field:OTS Item Total: Border: Thin Left
    
    [Field: OTS Sr NO]
    Use: Simple Field
    Set as: $$Line
    Format: "No Zero"
    Style:P9
    Align: Center
    [Field:OTS Item Description]
    Use: Simple Field
    Set as: if NOT $$IsSysName:$StockItemName then @@InvItemName else ""
    Style: P9
    Full Width: Yes
    ;Line:0
    
    [Field:OTS Item Description1]
    Use: Simple Field
    Set as:$SimpleItemDescription
    ;Style: P8
    ; Full Width: Yes
    
    [Field:OTS HSN Code]
    Use: Simple Field
    Set as: $GSTItemHSNCodeEx
    Style:P9
    [Field:OTS Billed Qty]
    Use: Qty Primary Field
    Set as: $BilledQty
    Style:P9
    [Field:OTS Rate]
    Use:  Rate Price Field
    Set as: $Rate
    Style:P9
    [Field:OTS Discount]
    Use: Number Field
    Set as: ""
    Set as: $Discount
    Format      : "NoZero,Percentage"
    Style:P9
    [Field:OTS Gross Amt]
    Use:Amount Forex Field
    Set as: $Amount
    Style:P9
    [Field:OTS GST Per]
    Use: Number Field
    Set as: If NOT $GSTIsTransLedEx Then "" Else $GSTClsfnIGSTRateEx
    Format      : "NoZero,Percentage"
    Set Always: Yes
    Style:P9
    
    [Field:OTS CGST Rate]
    Use: Number Field
    Set as: If NOT $GSTIsTransLedEx Then "" Else $GSTClsfnIGSTRateEx /2
    Format      : "NoZero,Percentage"
    Set Always: Yes
    Style:P9
    Invisible: If @@IGST > 0 then yes else no
    
    [Field:OTS CGST Amt]
    Use: Amount Field
    Set as: $Amount * #OTSCGSTRate / 100
    Style:P9
    Set Always: Yes
    Invisible: If @@IGST > 0 then yes else no
    [Field:OTS SGST Rate]
    Use: Number Field
    Set as: If NOT $GSTIsTransLedEx Then "" Else $GSTClsfnIGSTRateEx /2
    Format      : "NoZero,Percentage"
    Set Always: Yes
    Style:P9
    Invisible: If @@IGST > 0 then yes else no
    [Field:OTS SGST Amt]
    Use: Amount Field
    Set as: $Amount * #OTSSGSTRate / 100
    Style:P9
    Set Always: Yes
    Invisible: If @@IGST > 0 then yes else no
    [Field:OTS IGST Rate]
    Use: Number Field
    Set as: If NOT $GSTIsTransLedEx Then "" Else $GSTClsfnIGSTRateEx
    Format      : "NoZero,Percentage"
    Set Always: Yes
    Style:P9
    Invisible: If @@SGST > 0 then yes else no
    [Field:OTS IGST Amount]
    Use: Amount Field
    Set as: $Amount * #OTSIGSTRate / 100
    Style:P9
    Set Always: Yes
    Invisible: If @@SGST > 0 then Yes else no
    [Field:OTS Item Total]
    Use: Amount Field
    Set as: #OTSGrossAmt + #OTSCGSTAmt + #OTSSGSTAmt
    Set Always: Yes
    Style:P9
    [Line:OTS Invoice Body Coloumns Total]
    Use: OTS Invoice Body Coloumns
    Local: Field: Default: Type: String
    Local: Field: Default: Style: P9B
    Local: Field: Default: Align: Center
    Local: Field:OTS SrNo: Set as: ""
    Local: Field:OTS Item Description: Set as: "TOTAL"
    Local: Field:OTS HSN Code: Set as: ""
    Local: Field:OTS MRP Qty: Set as: ""
    Local: Field:OTS Billed Qty: Set as: ""
    Local: Field: OTS Rate: Set as: ""
    Local: Field:OTS Discount: Set as: ""
    Local: Field:OTS Gross Amt: Set as: $$CollAmtTotal:InventoryEntries:$Amount
    Local: Field:OTS GST Per: Set as: ""
    Local: Field:OTS CGST Rate: Set as: ""
    Local: Field: OTS CGST Amt: Set as: $$FilterAmtTotal:LedgerEntries:CGST1:$Amount
    Local: Field:OTS SGST Rate: Set as: ""
    Local: Field:OTS SGST Amt: Set as: $$FilterAmtTotal:LedgerEntries:SGST1:$Amount
    Local: Field:OTS Item Total: Set as: $Amount
    Border: Thin Top Bottom
    Space Bottom: 0.25
    Space Top: 0.25
    
    [System: Formula]
    SGST        :$$FilterAmtTotal:LedgerEntries:SGST1:$Amount
    SGST1        :$Name:Ledger:$LedgerName Contains $$LocaleString:"SGST"
    CGST        :$$FilterAmtTotal:LedgerEntries:CGST1:$Amount
    CGST1        :$Name:Ledger:$LedgerName Contains $$LocaleString:"CGST"
    IGST        :$$FilterAmtTotal:LedgerEntries:IGST1:$Amount
    IGST1        :$Name:Ledger:$LedgerName Contains $$LocaleString:"IGST"
    Round        :$$FilterAmtTotal:LedgerEntries:Round1:$Amount
    Round1        :$Name:Ledger:$LedgerName Contains $$LocaleString:"Round"
    [Part:OTS GST analisys Bankdetails ledgerentries]
    Left Part:VCH GST AnalysisDetails
    Right Part: OTSBankDetails, OTSLedgerEnteries
    Border: Thick Cover
    Common Border:Yes
    
    [#Part:VCH GST AnalysisDetails]
    Delete:Border   : Thin Box
    [#Part:VCH GST AnalysisDetails]
    Width:50% Page
    [Part:OTSBankDetails]
    Use:EXPINV BankDetails
    Border: Thick Left
    [#Line: EXPINV BankTitle]
                 
                        Fields      : Simple Field
                        Local       : Field : Simple Field    : Set as    : $$LocaleString:"Company's Bank Details"                           ;;; To Display Company's Bank Details
                        Local       : Field : Simple Field     : Full Width: Yes
         Local       : Field : Simple Field     : Style:P9B
         Space Top:0.5
         Space Bottom:0.25
        
    [#Line: EXPINV BankName]
    
                        Fields      : Medium Prompt, EXPINV BankName
                        Local       : Field : Medium Prompt     : Set as  : $$LocaleString:"Bank Name :"                                      ;;; To Display Bank Name
                        Local       : Field : Medium Prompt     : Width     : 18% Page
         Local  : Field : Medium Prompt  : Style:P9B
         Local  : Field:EXPINV BankName:Style:P9
    
                    [#Line: EXPINV BankAccNo]
    
                        Fields      : Medium Prompt, EXPINV BankAccountNo
                        Local       : Field : Medium Prompt    : Set as    : $$LocaleString:"A/c No. :"                                        ;;; To Display A/c No.
                        Local       : Field : Medium Prompt     : Width     : 18% Page
         Local  : Field : Medium Prompt  : Style:P9B
         Local  : Field:EXPINV BankAccountNo:Style:P9
    
        [#Line: EXPINV BankBranchInfo]
    
                        Fields      : Medium Prompt, EXPINV BankBranchName
                        Local       : Field : Medium Prompt    : Set as    : $$LocaleString:"Branch & IFS Code :"                              ;;; To Display Branch & IFS Code
                        Local       : Field : Medium Prompt     : Width     : 18% Page
         Local  : Field : Medium Prompt  : Style:P9B
         Local  : Field:EXPINV BankBranchName:Style:P9
    
    
    [Part:OTSLedgerEnteries]
    Line:OTSLedgerEnteries
    Repeat:OTSLedgerEnteries:Ledger Entries
    Border: Thick Left
    Common Border: Yes
    ;Scroll: Vertical
    Float: No
    [Line:OTSLedgerEnteries]
    Field: OTSLedgerName, OTSLedgerPercentage,OTSPercentageSing, OTSLedgerAmount
    Remove if: $LedgerName = $PartyLedgerName
    [Field:OTSLedgerName]
      Set as  : if ##SATCSDetails AND @@TaxLedgerHasTCS then $$LocaleString:"TCS : Income Tax" else +
             if NOT $$IsSysName:$LedgerName then $LedgerName else ""  ;;; used to print on invoice
       
            Style:P9B
            Align       : Right
            FullWidth   : Yes
      AbatementVal: If $$Number:$STXAbatementRate = 0 Then $$String:"0" Else $$String:$STXAbatementRate
      LedNarr  : (@@IsSales AND ##SALedgerNarr) OR (@@IsPurchase AND ##PULedgerNarr) AND $$Filtercount:LedgerEntries:LedgerNarrFltr > 0
      Option  : LeftAlignField : @@AcctsInvoice
      Width:8.7
    
    [Field:OTSLedgerPercentage]
    Use         : Rate Price Field
        Type        : Number
        Align       : Right
        Format      : "NoZero,Decimals:-1"
        Style:P9
    Set as      : if ##SATCSDetails AND @@TaxLedgerHasTCS AND NOT $$IsSysName:$TDSRateName:Ledger:$LedgerName then @@TCSITTaxRate else +
          $BasicRateOfInvoiceTax
        Inactive    : $$IsSysName:$LedgerName
        Invisible   : NOT @@InvWithRate
    Border: Thick Left
    Width: 4
    
    [Field:OTSPercentageSing]
    Set as:if $$IsEmpty:$BasicRateOfInvoiceTax then "" else "%"
    Set By Condition : @@TaxLedgerHasTCS AND NOT ($$IsSysName:$TDSRateName:Ledger:$LedgerName) : If $$IsEmpty:@@TCSITTaxRate Then "" Else "%"
        Inactive    : $$IsSysName:$LedgerName
        Invisible   : NOT @@InvWithRate
    Width: 2
    Style:P9
    
    [Field:OTSLedgerAmount]
    Use         : Amount Forex Field 
    Set as      : $$SignedAmount:$Amount:@@VchOpposite
    Border: Thick Left
    Align: Right
    Width: 8
    Style:P9
    [Part:OTSInvoiceAmtwordandamount]
    Left Part: OTSAmountinWord
    Right Part:OTSInvoiceAmount
    Border: Thick Cover
    Common Border: Yes
    [Part:OTSAmountinWord]
    Line:OTSAmountinWord
    [Line:OTSAmountinWord]
    Field: Medium Prompt, Name Field
    Local: Field: Medium Prompt: Set as: "Amount In Words"
    Local: Field: Medium Prompt:Style:P9B
    Local: Field: Name Field: Set as:$$InWords:$Amount +"  "+ "Only."
    Local: Field: Name Field: Full Width: Yes
    Local: Field: Name Field: Line:0
    Local: Field: Name Field:Style:P9
    Space Top:0.25
    Space Bottom:0.25
    
    [Part:OTSInvoiceAmount]
    Line:OTSInvoiceAmount
    [Line:OTSInvoiceAmount]
    Field: Name Field, Amount Field
    Local: Field: Name Field: Set as: "Invoice Total"
    Local: Field: Name Field: Border: Thick Left
    Local: Field: Name Field: Width:26.5
    Local: Field: Name Field: Align: Right
    Local: Field: Name Field: Style:P9B
    Local: Field: Amount Field: Set as: $Amount
    Local: Field: Amount Field: Width:8
    Local: Field: Amount Field: Border: Thick Left
    Local: Field: Amount Field: Style:P9B
    Space Top:0.25
    Space Bottom:0.25
    [Part:OTSSingnatureClosingBalanceTerms]
    Left Part: OTSTermsandClosing
    Right Part: OTSCustomer Signature, OTSSignature
    Border:Thick Box
    [Part:OTSTermsandClosing]
    Part: OTSTermsPart
    Vertical:Yes
    Width:50% Page
    [Part:OTSTermsPart]
    Line:OTSTermsPart,OTSTermsPart1,OTSTermsPart2,OTANARRATION
    Border: Thick Bottom
    [Line:OTSTermsPart]
    Field: Name Field
    Local: Field: Name Field:Set as: "GOODS ONCE SOLD WILL "
    BORDER: THICK BOTTOM
    ;Local: Field: Name Field:Set as: ""
    Local: Field: Name Field: Style: P9
    Local: Field: Name Field: Align: Left
    Local: Field: Name Field: Full Width: Yes
    
    [Line:OTSTermsPart1]
    Field: Name Field
    Local: Field: Name Field:Set as: "NOT BE TAKEN BACK OR "
    BORDER: THICK BOTTOM
    ;Local: Field: Name Field:Set as: ""
    Local: Field: Name Field: Style: P9
    Local: Field: Name Field: Align: Left
    Local: Field: Name Field: Full Width: Yes
    
    [Line:OTSTermsPart2]
    Field: Name Field
    Local: Field: Name Field:Set as: "EXCHANGED."
    BORDER: THICK BOTTOM
    ;Local: Field: Name Field:Set as: ""
    Local: Field: Name Field: Style: P9
    Local: Field: Name Field: Align: Left
    Local: Field: Name Field: Full Width: Yes
    
    [Line:OTANARRATION]
    Field: Name Field
    Local: Field: Name Field: set as : $Narration
    Local: Field: Name Field: Full Width: Yes
    Local: Field: Name Field: Style: P9
    Local: Field: Name Field: Line:0
    Space Top:3
    [Part:OTSCustomer Signature]
    Line: For OTSCustomer Signature, OTSAcceptance
    Border: Thick Left
    [Line:For OTSCustomer Signature]
    Field: Name Field
    Local: Field: Name Field: Set as: "For"+" "+@@SimpleOtherPartyName
    Local: Field: Name Field: Full Width: Yes
    Local: Field: Name Field: Style: P9B
    Local: Field: Name Field: Align: Center
    Space Top:0.5
    [Line:OTSAcceptance]
    Field: Name Field
    Local: Field: Name Field: Set as: "I received goods in good condition and I have read the terms & condition. I agree with it."
    Local: Field: Name Field: Full Width: Yes
    Local: Field: Name Field: Style: P9
    Local: Field: Name Field: Line:0
    Space Top:3
    
    [Part:OTSSignature]
    Line: ForOTSSignature, OTSAuthorised
    Border: Thick Left
    Width:36.5
    [Line:ForOTSSignature]
    Field: Name Field
    Local: Field: Name Field: Set as: "For"+" "+@@CmpMailName
    Local: Field: Name Field: Full Width: Yes
    Local: Field: Name Field: Style: P9B
    Local: Field: Name Field: Align: Center
    Space Top:0.5
    [Line:OTSAuthorised]
    Field: Name Field
    Local: Field: Name Field: Set as: "Proprietor / Manager"
    Local: Field: Name Field: Full Width: Yes
    Local: Field: Name Field: Style: P9B
    Local: Field: Name Field: Align: Center
    Space Top:3
    [Part:OTSJuri]
    Line:OTS Juridiction
    [Line:OTS Juridiction]
    Field: Name Field
    Local: Field: Name Field: Full Width: Yes
    Local: Field: Name Field: Set as: "SUBJECT TO BAREILLY JURISDISCTION ONLY."
    Local: Field: Name Field: Align: Center
    
    
     


  2. balajimg

    balajimg Active Member


    Why do you assume there's something missing
     


  3. PRAPTI

    PRAPTI Member


    Not in my opinion, but I assume that someone can provide me with some new and exciting ideas to edit it
     


  4. udaya

    udaya Active Member


    fantastic job bro......
     


  5. mpal2311

    mpal2311 Active Member


    Good Job. Keep it up.
     


  6. PRAPTI

    PRAPTI Member


    Thanks
     


  7. PRAPTI

    PRAPTI Member


    Just one thing I want, when the name is too much long, then the vertical lines are shifted alongside. I want this the letters should be shifted in the next line.
     


Share This Page